SMARTFORM X-System Comparer

[Tron]

Moin.
Auf der Suche nach einer geeigneten Möglichkeit Smartform Formularversionen über die Systemgrenzen hinaus zu vergleichen, bin ich leider nirgends fündig geworden.
Der Bedarf an einem solchen Tools scheint mir jedoch sehr groß zu sein , deshalb .....

smart3.png (30.82 KiB) Viewed 773 times

smart2.png (16.92 KiB) Viewed 775 times

Der Smartformvergleicher besteht aus:
1.) einem RFC-fähigen Funktionsbaustein der eine Smartform Formular Definition als XML einliest und
via Tabellenparameter über die Schnittstelle bereitstellt. Dieser Funktionsbaustein sollte in alle verbundenen Systeme transportiert werden.

2.) Einem Report, welcher die Definitionen vergleicht (was einfacher klingt, als es ist.)
Wenn man genau wissen möchte was unterschiedlich ist, kann man die Ergebnistabelle (lt_xx) des Bausteins RS_CMP_COMPUTE_DELTA auf einem ALV ausgeben.
Die Differenzen sind gekennzeichnet (oder was er dafür hält) . Alle Tags eines Smartform formulars, welche generell unterschiedlich sind, wie FORMNAME LASTDATE ..
werden über ein Range Objekt abgefangen, da sonst jeder Vergleich zu Differenzen führen würde. (Also falls noch jemand etwas entdecken sollte...)
Mein Tipp wäre hier noch, die Liste ab der Differenz, Richtung Anfang zu gehen, bis zum Element INAME , das Element kann man dann in Smartforms suchen !
Der Vergleich reagiert auf Übersetzungen und funktioniert sogar mit nicht aktivierten Formularen.
Der Report kann im Entwicklungssystem bleiben, solange man nicht von den angeschlossenen Systemen aus vergleichen möchte.

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. *&---------------------------------------------------------------------*
2. *& Report  ZTEST_SF_COMP_ALV
3. *&
4. *&---------------------------------------------------------------------*
5. *&
6. *&
7. *&---------------------------------------------------------------------*
8. REPORT ztest_sf_comp_alv.
9. TABLES: sscrfields.
10.  
11. TYPE-POOLS:ctslg,icon,slis.
12.  
13. CONSTANTS indx_id TYPE indx_srtfd VALUE 'RSEDCRESUL'.
14.  
15. TYPES: BEGIN OF ty_output,
16.          line1  TYPE eddispline,
17.          line2  TYPE  eddispline,
18.          text1  TYPE  rsline,
19.          text2  TYPE  rsline,
20.          flag1  TYPE sedflgdelt,
21.          flag2  TYPE  sedflgdelt,
22.          iname1 TYPE rsline,
23.          iname2 TYPE rsline,
24.        END OF ty_output.
25.  
26.  
27. TYPES : t_tr TYPE TABLE OF rsedcresul.
28.  
29. * Grid Parameter
30. DATA: ok_code            LIKE sy-ucomm,
31.       g_container        TYPE scrfname VALUE 'GRID1',
32.       grid1              TYPE REF TO cl_gui_alv_grid,
33.       g_custom_container TYPE REF TO cl_gui_custom_container,
34.       g_dock_container   TYPE REF TO cl_gui_docking_container,
35.       is_variant         TYPE disvariant.
36. *--- Field catalog table
37. DATA gt_fieldcat TYPE lvc_t_fcat WITH HEADER LINE.
38. *--- Layout structure
39. DATA gs_layout TYPE lvc_s_layo .
40.  
41. * LT_EXCLUDE => Tabelle zum Ausschliessen von Funktionen innerhalb
42. * der Toolbar des ALV-Grid
43. DATA: lt_exclude TYPE ui_functions,
44.       ls_exclude TYPE ui_func.
45.  
46. DATA it_data TYPE TABLE OF ty_output .
47. DATA gv_title(80) VALUE 'Comparing..'.
48. *---------------------------------------------------------------------*
49. *       CLASS lcl_event_handler DEFINITION
50. *---------------------------------------------------------------------*
51. *
52. *---------------------------------------------------------------------*
53. CLASS lcl_event_handler DEFINITION .
54.   PUBLIC SECTION .
55.     METHODS:
56. *--To add new functional buttons to the ALV toolbar
57.       handle_toolbar FOR EVENT toolbar OF cl_gui_alv_grid
58.         IMPORTING e_object e_interactive ,
59.  
60. *--To implement user commands
61.       handle_user_command
62.                     FOR EVENT user_command OF cl_gui_alv_grid
63.         IMPORTING e_ucomm .
64.  
65.  
66.   PRIVATE SECTION.
67. ENDCLASS.                    "lcl_event_handler DEFINITION
68.  
69.  
70.  
71. *---------------------------------------------------------------------*
72. *       CLASS lcl_event_handler IMPLEMENTATION
73. *---------------------------------------------------------------------*
74. *
75. *---------------------------------------------------------------------*
76. CLASS lcl_event_handler IMPLEMENTATION .
77.  
78. *--Handle Toolbar
79.   METHOD handle_toolbar.
80.     PERFORM handle_toolbar USING e_object e_interactive .
81.   ENDMETHOD .                    "handle_toolbar
82.  
83. *--Handle User Command
84.   METHOD handle_user_command .
85.     PERFORM handle_user_command USING e_ucomm .
86.   ENDMETHOD.                    "handle_user_command
87.  
88.  
89. ENDCLASS.                    "lcl_event_handler IMPLEMENTATION
90.  
91. DATA gr_event_handler TYPE REF TO lcl_event_handler .
92.  
93. * Info Destinationen
94. DATA: des1_info TYPE rfcsi,
95.       des2_info TYPE rfcsi.
96. *DATA lv_mandt1(3).
97. *DATA lv_mandt2(3).
98.  
99. DATA rt_exc TYPE smum_xmltb-cname.
100. RANGES gr_excl FOR rt_exc.
101.  
102. START-OF-SELECTION.
103.  
104.   SELECTION-SCREEN FUNCTION KEY 1.
105.  
106.   PARAMETERS:
107.     p_form1 TYPE tdsfname OBLIGATORY MATCHCODE OBJECT sh_stxfadm,
108.     p_form2 TYPE tdsfname OBLIGATORY MATCHCODE OBJECT sh_stxfadm.
109.  
110.   SELECTION-SCREEN SKIP 1.
111.   SELECTION-SCREEN BEGIN OF BLOCK b WITH FRAME TITLE text-001.
112.   PARAMETERS p_des1 TYPE rfcdes-rfcdest OBLIGATORY DEFAULT 'NONE'.
113.   SELECTION-SCREEN END OF BLOCK b.
114.  
115.   SELECTION-SCREEN BEGIN OF BLOCK a WITH FRAME TITLE text-002.
116.   PARAMETERS p_des2 TYPE rfcdes-rfcdest OBLIGATORY DEFAULT 'NONE'.
117.   SELECTION-SCREEN END OF BLOCK a.
118.  
119. END-OF-SELECTION.
120.  
121.   PERFORM check_avail.
122.   IF des1_info IS INITIAL.
123.     MESSAGE s368(00) DISPLAY LIKE 'E' WITH p_des1 ':RFC-Destination not reachable.' .
124.    return.
125.   ENDIF.
126.  
127.   IF des2_info IS INITIAL.
128.     MESSAGE s368(00) DISPLAY LIKE 'E' WITH p_des2 ':RFC-Destination not reachable.' .
129.     return.
130.   ENDIF.
131.  
132.   PERFORM fill_exclude_range.
133.  
134.  
135.   PERFORM compare_sf.
136. *&---------------------------------------------------------------------*
137. *&      Form  Check_avail
138. *&---------------------------------------------------------------------*
139. *       text
140. *----------------------------------------------------------------------*
141. *      -->DEST       text
142. *----------------------------------------------------------------------*
143. FORM check_avail.
144.   DATA:
145. "  info LIKE rfcsi,
146.   msg_text(80) TYPE c. "Message text
147.  
148.   CALL FUNCTION 'RFC_SYSTEM_INFO'
149.     DESTINATION p_des1
150.     IMPORTING
151.       rfcsi_export          = des1_info
152.     EXCEPTIONS
153.       communication_failure = 1 MESSAGE msg_text
154.       system_failure        = 2 MESSAGE msg_text.
155.  
156.   CALL FUNCTION 'RFC_SYSTEM_INFO'
157.     DESTINATION p_des2
158.     IMPORTING
159.       rfcsi_export          = des2_info
160.     EXCEPTIONS
161.       communication_failure = 1 MESSAGE msg_text
162.       system_failure        = 2 MESSAGE msg_text.
163.  
164. ENDFORM.                    "Check_avail
165. *&---------------------------------------------------------------------*
166. *&      Form  write_for_display
167. *&---------------------------------------------------------------------*
168. *       text
169. *----------------------------------------------------------------------*
170. FORM write_for_display.
171.   DATA: t1(80),t2(80).
172.   DATA: info         LIKE rfcsi,
173.         msg_text(80) TYPE c. "Message text
174.  
175.   FORMAT COLOR COL_HEADING.
176.   WRITE: / '*** STATUS RFC-connectivity ***' , AT sy-linsz space.
177.   ULINE.
178.   FORMAT COLOR OFF.
179.  
180.   CLEAR msg_text.
181.   CALL FUNCTION 'RFC_PING'
182.     DESTINATION p_des2
183.     EXCEPTIONS
184.       communication_failure = 1 MESSAGE msg_text
185.       system_failure        = 2 MESSAGE msg_text.
186.  
187.  
188.   t1 = p_des2.
189.   CONDENSE t1.
190.  
191.   IF msg_text IS INITIAL.
192.     CONCATENATE 'Destination :' t1 'reachable.' INTO t2 SEPARATED BY space.
193.     FORMAT INTENSIFIED OFF.
194.  
195.     WRITE: / icon_led_green AS ICON,
196.                 t2 COLOR COL_POSITIVE.
197.  
198.   ELSE.
199.     CONCATENATE 'Destination :' t1 'not reachable.' INTO t2 SEPARATED BY space.
200.     FORMAT INTENSIFIED OFF.
201.  
202.     WRITE: /      icon_led_red AS ICON,
203.                   t2 COLOR COL_NEGATIVE.
204.  
205.   ENDIF.
206.  
207.   CLEAR msg_text.
208.   CALL FUNCTION 'RFC_PING'
209.     DESTINATION p_des1
210.     EXCEPTIONS
211.       communication_failure = 1 MESSAGE msg_text
212.       system_failure        = 2 MESSAGE msg_text.
213.  
214.  
215.   t1 = p_des1.
216.   CONDENSE t1.
217.  
218.   IF msg_text IS INITIAL.
219.     CONCATENATE 'Destination :' t1 'reachable.' INTO t2 SEPARATED BY space.
220.     FORMAT INTENSIFIED OFF.
221.  
222.     WRITE: / icon_led_green AS ICON,
223.                 t2 COLOR COL_POSITIVE.
224.  
225.   ELSE.
226.     CONCATENATE 'Destination :' t1 'not reachable.' INTO t2 SEPARATED BY space.
227.     FORMAT INTENSIFIED OFF.
228.  
229.     WRITE: /      icon_led_red AS ICON,
230.                   t2 COLOR COL_NEGATIVE.
231.  
232.   ENDIF.
233.  
234. ENDFORM.                    "write_for_display
235.  
236. AT SELECTION-SCREEN.
237.   IF sy-ucomm = 'FC01'." n = 1 up to 5
238. * Teste Erreichbarkeit
239.  
240.     PERFORM write_for_display.
241.  
242.     CALL FUNCTION 'C14A_POPUP_LIST_DISPLAY'
243.       EXPORTING
244.         i_callback            = 'WRITE_FOR_DISPLAY'
245.         i_callback_program    = sy-repid
246.         i_title               = 'RFC-connections'
247.         i_col                 = 4
248.         i_row                 = 4
249.         i_width               = 84
250.         i_height              = 10
251. *       I_TEXT_WIDTH          =
252. *       I_FLG_SHOW_PRINT_BUTTON = ESP1_FALSE
253.       EXCEPTIONS
254.         no_callback_specified = 1
255.         OTHERS                = 2.
256.  
257.     IF sy-subrc <> 0.
258.       MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
259.               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
260.     ENDIF.
261.   ENDIF.
262.  
263. INITIALIZATION.
264.  
265.   sscrfields-functxt_01 = '@FC@ Check RFC-Destinations'(003).
266.  
267. FORM compare_sf.
268.  
269.   DATA t_sftab1 TYPE TABLE OF smum_xmltb.
270.   DATA t_sftab2 TYPE TABLE OF smum_xmltb.
271.   FIELD-SYMBOLS <sft> TYPE smum_xmltb.
272.   DATA lt_t1 TYPE rswsourcet.
273.   DATA lt_t2 TYPE rswsourcet.
274.   DATA lv_equal(1).
275.   DATA lt_xx TYPE TABLE OF rsedcresul.
276.   DATA lv_str TYPE string.
277.   DATA msg_text(80).
278.   DATA lv_lastname1(20).
279.   DATA lv_lastname2(20).
280.   DATA ls_data TYPE ty_output .
281.  
282.  
283.  
284.   DATA ls_xx TYPE rsedcresul.
285.  
286.   CALL FUNCTION 'Z_BC_READSFXML' DESTINATION p_des1
287.     EXPORTING
288.       i_form                  = p_form1
289.       i_langu                 = ' '
290.     TABLES
291.       sftab                   = t_sftab1
292. *     RETURN                  =
293.     EXCEPTIONS
294.       form_not_exist          = 1
295.       wrong_access_to_archive = 2
296.       communication_failure   = 3 MESSAGE msg_text
297.       system_failure          = 4 MESSAGE msg_text
298.       OTHERS                  = 5.
299.  
300.   IF NOT msg_text IS INITIAL.
301.     MESSAGE s000(su) WITH msg_text 'under destination' p_des1 DISPLAY LIKE 'E'.
302.     return.
303.   ENDIF.
304.  
305.   IF sy-subrc EQ 1.
306.     MESSAGE s000(su) WITH 'Form'  p_form1 'does not exist in' p_des1 DISPLAY LIKE 'E'.
307.     return.
308.   ENDIF.
309.  
310.   LOOP AT t_sftab1 ASSIGNING <sft> WHERE cname IN gr_excl AND type NE 'A' .
311.     CONCATENATE  <sft>-cname '-' <sft>-cvalue INTO lv_str.
312.     APPEND lv_str TO lt_t1.
313.   ENDLOOP.
314.  
315.   CALL FUNCTION 'Z_BC_READSFXML' DESTINATION p_des2
316.     EXPORTING
317.       i_form                  = p_form2
318.       i_langu                 = ' '
319.     TABLES
320.       sftab                   = t_sftab2
321. *     RETURN                  =
322.     EXCEPTIONS
323.       form_not_exist          = 1
324.       wrong_access_to_archive = 2
325.       communication_failure   = 3 MESSAGE msg_text
326.       system_failure          = 4 MESSAGE msg_text
327.       OTHERS                  = 5.
328.  
329.   IF NOT msg_text IS INITIAL.
330.     MESSAGE s000(su) WITH msg_text 'under destination' p_des2 DISPLAY LIKE 'E'.
331.     RETURN.
332.   ENDIF.
333.  
334.   IF sy-subrc EQ 1.
335.     MESSAGE s000(su) WITH 'Form'  p_form2 'does not exist in' p_des2 DISPLAY LIKE 'E'.
336.     RETURN.
337.   ENDIF.
338.  
339.   LOOP AT t_sftab2 ASSIGNING <sft> WHERE cname IN gr_excl AND type NE 'A' .
340.     CONCATENATE <sft>-cname '-' <sft>-cvalue INTO lv_str.
341.     APPEND lv_str TO lt_t2.
342.   ENDLOOP.
343.  
344.   CALL FUNCTION 'RS_CMP_COMPUTE_DELTA'
345.     EXPORTING
346. *     COMPARE_MODE            = '1'
347. *     FLG_EXT_IGNORE          = ' '
348.       ignore_case_differences = ' '
349. *     FLG_WB99                = ' '
350.     IMPORTING
351.       flg_equal               = lv_equal
352.     TABLES
353.       text_tab1               = lt_t2
354.       text_tab2               = lt_t1
355.       text_tab_res            = lt_xx
356.     EXCEPTIONS
357.       parameter_invalid       = 1
358.       difference_not_found    = 2
359.       OTHERS                  = 3.
360.  
361.  
362.   IF lv_equal IS INITIAL.
363.  
364.     LOOP AT lt_xx INTO ls_xx.
365.       MOVE-CORRESPONDING ls_xx TO ls_data.
366. *----------------------------------------------------------
367.       IF strlen( ls_data-text1 ) > 5.
368.         IF ls_data-text1(5) = 'INAME'.
369.           lv_lastname1 = ls_data-text1+6.
370.         ENDIF.
371.       ENDIF.
372.       IF NOT lv_lastname1 IS INITIAL.
373.         ls_data-iname1 = lv_lastname1.
374.       ENDIF.
375.       IF ls_data-line1 = space.
376.         CLEAR ls_data-iname1.
377.       ENDIF.
378. *----------------------------------------------------------
379.       IF strlen( ls_data-text2 ) > 5.
380.         IF ls_data-text2(5) = 'INAME'.
381.           lv_lastname2 = ls_data-text2+6.
382.         ENDIF.
383.       ENDIF.
384.       IF NOT lv_lastname2 IS INITIAL.
385.         ls_data-iname2 = lv_lastname2.
386.       ENDIF.
387.       IF ls_data-line2 = space.
388.         CLEAR ls_data-iname2.
389.       ENDIF.
390. *----------------------------------------------------------
391.  
392.       APPEND ls_data TO it_data.
393.     ENDLOOP.
394.  
395.     CALL SCREEN 100.
396.  
397.     MESSAGE s000(su) WITH 'Forms are not equal !' DISPLAY LIKE 'E'.
398.  
399.   ELSE.
400.     MESSAGE s000(su) WITH 'Forms are equal !'.
401.   ENDIF.
402.  
403. ENDFORM.
404.  
405. FORM fill_exclude_range.
406.  
407.   CLEAR   gr_excl .
408.  
409.   gr_excl-sign = 'E'.
410.   gr_excl-option = 'EQ'.
411.  
412.   gr_excl-low = 'FORMNAME'. APPEND gr_excl.
413.   gr_excl-low = 'FIRSTUSER'. APPEND gr_excl.
414.   gr_excl-low = 'FIRSTDATE'. APPEND gr_excl.
415.   gr_excl-low = 'FIRSTTIME'. APPEND gr_excl.
416.   gr_excl-low = 'LASTUSER'. APPEND gr_excl.
417.   gr_excl-low = 'LASTDATE'. APPEND gr_excl.
418.   gr_excl-low = 'LASTTIME'. APPEND gr_excl.
419.   gr_excl-low = 'CAPTION'. APPEND gr_excl.
420. *  gr_excl-low = 'item'. APPEND gr_excl.
421.   gr_excl-low = 'DEVCLASS'. APPEND gr_excl.
422.   gr_excl-low = 'STATUS'. APPEND gr_excl.
423.   gr_excl-low = 'LANGU'. APPEND gr_excl.
424.  
425.  
426. ENDFORM.
427.  
428. *&---------------------------------------------------------------------*
429. *&      Module  PBO  OUTPUT
430. *&---------------------------------------------------------------------*
431. *       text
432. *----------------------------------------------------------------------*
433. MODULE pbo OUTPUT.
434.  
435.   IF g_custom_container IS INITIAL.
436.  
437.     IF cl_gui_alv_grid=>offline( ) IS INITIAL.
438.       CREATE OBJECT g_custom_container
439.         EXPORTING
440.           container_name = g_container.
441.       CREATE OBJECT grid1
442.         EXPORTING
443.           i_parent = g_custom_container.
444.     ELSE.
445.  
446. *    Hintergrund
447.       CREATE OBJECT grid1
448.         EXPORTING
449.           i_parent = g_dock_container.
450.  
451.     ENDIF.
452.  
453. *    CREATE OBJECT g_custom_container
454. *      EXPORTING
455. *        container_name = g_container.
456. *
457. *    CREATE OBJECT grid1
458. *      EXPORTING
459. *        i_parent = g_custom_container.
460.  
461. *--Creating an instance for the event handler
462.     CREATE OBJECT gr_event_handler .
463.  
464. *----Preparing field catalog.
465.     PERFORM prepare_field_catalog TABLES gt_fieldcat[] .
466. *----Preparing layout structure
467.     PERFORM prepare_layout CHANGING gs_layout .
468. *----Preparing Disable Toolbar Buttons
469.     PERFORM change_buttons .
470.  
471.     is_variant-report = sy-repid.
472.     IF sy-batch IS INITIAL.
473.       is_variant-variant = '/GLOB_DEF'.
474.     ELSE.
475.       is_variant-variant = '/GLOB_JOB'.
476.     ENDIF.
477.  
478. *'X':  nur globales Speichern
479. *'U':  nur benutzerspezifisches Speichern
480. *'A':  entspricht 'X' und 'U'
481. *SPACE:kein Speichern
482.  
483.     CALL METHOD grid1->set_table_for_first_display
484.       EXPORTING
485.         is_variant           = is_variant
486.         i_save               = 'X'
487.         is_layout            = gs_layout
488.         it_toolbar_excluding = lt_exclude
489.       CHANGING
490.         it_outtab            = it_data[]
491.         it_fieldcatalog      = gt_fieldcat[].
492.  
493.  
494. *--Registering handler methods to handle ALV Grid events JG
495.  
496.     SET HANDLER gr_event_handler->handle_toolbar FOR grid1.
497.     SET HANDLER gr_event_handler->handle_user_command FOR grid1.
498.  
499.     CALL METHOD grid1->set_toolbar_interactive.
500.  
501. * Der GRID1 wird noch refreshed
502.     CALL METHOD grid1->refresh_table_display.
503.  
504.   ENDIF.
505.  
506.   SET PF-STATUS 'MAIN100'.
507.   CONCATENATE 'Comparing' p_form1 'with' p_form2 INTO gv_title SEPARATED BY space.
508.   SET TITLEBAR 'AUSW' WITH gv_title.
509.  
510. ENDMODULE.
511. *&---------------------------------------------------------------------*
512. *&      Module  PAI  INPUT
513. *&---------------------------------------------------------------------*
514. *       text
515. *----------------------------------------------------------------------*
516. MODULE pai INPUT.
517. *   to react on oi_custom_events:
518.   CALL METHOD cl_gui_cfw=>dispatch.
519.   CASE ok_code.
520.     WHEN 'EXIT'.
521.       PERFORM exit_program.
522.     WHEN OTHERS.
523. *     do nothing
524.   ENDCASE.
525.   CLEAR ok_code.
526.  
527. ENDMODULE.
528. *---------------------------------------------------------------------*
529. *       FORM EXIT_PROGRAM                                             *
530. *---------------------------------------------------------------------*
531. FORM exit_program.
532. *  CALL METHOD G_CUSTOM_CONTAINER->FREE.
533. *  CALL METHOD CL_GUI_CFW=>FLUSH.
534.   LEAVE TO SCREEN 0.
535. ENDFORM.                    "EXIT_PROGRAM
536. *&--------------------------------------------------------------------*
537. *&      Form  Change_buttons
538. *&--------------------------------------------------------------------*
539. *       text
540. *---------------------------------------------------------------------*
541. FORM change_buttons .
542. * Kein Symbol für Drucken / Graphik / Info
543.   ls_exclude = cl_gui_alv_grid=>mc_fc_print_back.
544.   APPEND ls_exclude TO lt_exclude.
545.   ls_exclude = cl_gui_alv_grid=>mc_fc_graph.
546.   APPEND ls_exclude TO lt_exclude.
547.   ls_exclude = cl_gui_alv_grid=>mc_fc_info.
548.   APPEND ls_exclude TO lt_exclude.
549.  
550. ENDFORM.                    "Change_buttons
551.  
552. *&--------------------------------------------------------------------*
553. *&      Form  handle_toolbar
554. *&--------------------------------------------------------------------*
555. *       text
556. *---------------------------------------------------------------------*
557. *      -->I_OBJECT   text
558. *---------------------------------------------------------------------*
559. FORM handle_toolbar USING i_object TYPE REF TO cl_alv_event_toolbar_set
560. e_interactive .
561.  
562.   DATA: ls_toolbar TYPE stb_button.
563.  
564. * Paltzhalter / Seperator
565.   CLEAR ls_toolbar.
566.   MOVE 3 TO ls_toolbar-butn_type.
567.   APPEND ls_toolbar TO i_object->mt_toolbar.
568.  
569.  
570. ** Button Show Differences
571.   CLEAR ls_toolbar.
572.   MOVE 'SET_FILTER' TO ls_toolbar-function.                 "#EC NOTEXT
573.   MOVE icon_filter TO ls_toolbar-icon.
574.   MOVE 'Filter Differences'(203) TO ls_toolbar-quickinfo.
575.   MOVE ' Filter Differences'(203) TO ls_toolbar-text.
576.   MOVE ' ' TO ls_toolbar-disabled.                          "#EC NOTEXT
577.   APPEND ls_toolbar TO i_object->mt_toolbar.
578.  
579. ** Button Delete Filter Differences
580.   CLEAR ls_toolbar.
581.   MOVE 'DEL_FILTER' TO ls_toolbar-function.                 "#EC NOTEXT
582.   MOVE icon_filter_undo TO ls_toolbar-icon.
583.   MOVE 'Delete Filter Differences'(203) TO ls_toolbar-quickinfo.
584.   MOVE ' Delete Filter Differences'(203) TO ls_toolbar-text.
585.   MOVE ' ' TO ls_toolbar-disabled.                          "#EC NOTEXT
586.   APPEND ls_toolbar TO i_object->mt_toolbar.
587.  
588. ** Paltzhalter / Seperator
589. *  CLEAR ls_toolbar.
590. *  MOVE 3 TO ls_toolbar-butn_type.
591. *  APPEND ls_toolbar TO i_object->mt_toolbar.
592.  
593.  
594.  
595. ENDFORM .                    "handle_toolbar
596. *&---------------------------------------------------------------------*
597. *&      Form  handle_user_command
598. *&---------------------------------------------------------------------*
599. *       text
600. *----------------------------------------------------------------------*
601.  
602. FORM handle_user_command USING i_ucomm TYPE syucomm .
603.   DATA lt_selected_rows TYPE lvc_t_roid .
604.   DATA ls_selected_row TYPE lvc_s_roid .
605.   DATA lv_name TYPE epsfili-name.
606.   DATA lv_flag(1).
607.   DATA lv_stable TYPE lvc_s_stbl.
608.   DATA ls_filter TYPE lvc_s_filt.
609.   DATA lt_filter TYPE lvc_t_filt.
610.  
611.   CASE i_ucomm .
612.  
613.     WHEN 'SET_FILTER'.
614.       ls_filter-fieldname = 'FLAG1'. "Field Name
615.       ls_filter-sign = 'I'.
616.       ls_filter-option = 'NE'.
617.       ls_filter-low = ' '. "Filter Value
618.       APPEND ls_filter TO lt_filter.
619.  
620.       ls_filter-fieldname = 'FLAG2'. "Field Name
621.       ls_filter-sign = 'I'.
622.       ls_filter-option = 'NE'.
623.       ls_filter-low = ' '. "Filter Value
624.       APPEND ls_filter TO lt_filter.
625.  
626.       CALL METHOD grid1->set_filter_criteria
627.         EXPORTING
628.           it_filter = lt_filter.
629.  
630.     WHEN 'DEL_FILTER'.
631.       CALL METHOD grid1->get_filter_criteria
632.         IMPORTING
633.           et_filter = lt_filter.
634.  
635.       DELETE lt_filter WHERE fieldname = 'FLAG1' OR fieldname = 'FLAG2'.
636.  
637.       CALL METHOD grid1->set_filter_criteria
638.         EXPORTING
639.           it_filter = lt_filter.
640.  
641.     WHEN OTHERS.
642.   ENDCASE .
643.  
644.   lv_stable-row = 'X'.
645.   CALL METHOD grid1->refresh_table_display
646.     EXPORTING
647.       is_stable = lv_stable.
648. *    EXCEPTIONS
649. *      finished  = 1
650. *      OTHERS    = 2.
651.  
652. ENDFORM.                    "handle_user_command
653.  
654. *&--------------------------------------------------------------------*
655. *&      Form  prepare_field_catalog
656. *&--------------------------------------------------------------------*
657. *       text
658. *---------------------------------------------------------------------*
659. *      -->PT_FIELDCATtext
660. *---------------------------------------------------------------------*
661. FORM prepare_field_catalog TABLES pt_fieldcat TYPE lvc_t_fcat .
662.  
663. *  DATA ls_fcat TYPE lvc_s_fcat .
664. *  DATA lv_depth TYPE i.
665.  
666.   DATA l_struc TYPE dd02l-tabname.
667.   DATA: ls_fieldcat TYPE lvc_s_fcat.
668.   FIELD-SYMBOLS: <p> TYPE lvc_s_fcat.
669.  
670.   l_struc = indx_id .
671.   CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
672.     EXPORTING
673.       i_structure_name       = l_struc
674.     CHANGING
675.       ct_fieldcat            = pt_fieldcat[]
676.     EXCEPTIONS
677.       inconsistent_interface = 1
678.       program_error          = 2
679.       OTHERS                 = 3.
680.  
681.   IF sy-subrc <> 0.
682. *--Exception handling
683.   ENDIF.
684.  
685.   READ TABLE pt_fieldcat INTO ls_fieldcat WITH KEY fieldname = 'TEXT1'.
686.   IF sy-subrc = 0.
687.     ls_fieldcat-col_pos = 7.
688.     ls_fieldcat-fieldname = 'INAME1'.
689.     ls_fieldcat-ref_table = space.
690.     ls_fieldcat-tabname = space.
691.     APPEND ls_fieldcat TO pt_fieldcat.
692.     ls_fieldcat-col_pos = 8.
693.     ls_fieldcat-fieldname = 'INAME2'.
694.     APPEND ls_fieldcat TO pt_fieldcat.
695.   ENDIF.
696.  
697.   LOOP AT pt_fieldcat ASSIGNING <p>.
698.  
699.     CASE <p>-fieldname.
700.       WHEN 'INAME1'.
701.         <p>-scrtext_l = 'Element A'.
702.         <p>-scrtext_m = 'Elem.A'.
703.         <p>-scrtext_s = 'EA'.
704.       WHEN 'INAME2'.
705.         <p>-scrtext_l = 'Element B'.
706.         <p>-scrtext_m = 'Elem.B'.
707.         <p>-scrtext_s = 'EB'.
708.       WHEN 'LINE1'.
709.         <p>-scrtext_l = 'Line A'.
710.         <p>-scrtext_m = 'Line A'.
711.         <p>-scrtext_s = 'LA'.
712.       WHEN 'LINE2'.
713.         <p>-scrtext_l = 'Line B'.
714.         <p>-scrtext_m = 'Line B'.
715.         <p>-scrtext_s = 'LB'.
716.       WHEN 'TEXT1'.
717.         <p>-scrtext_l = 'Source A'.
718.         <p>-scrtext_m = 'Src A'.
719.         <p>-scrtext_s = 'A'.
720.       WHEN 'TEXT2'.
721.         <p>-scrtext_l = 'Source B'.
722.         <p>-scrtext_m = 'Src B'.
723.         <p>-scrtext_s = 'B'.
724.       WHEN 'FLAG1'.
725.         <p>-scrtext_l = 'Change A'.
726.         <p>-scrtext_m = 'C-Flg A'.
727.         <p>-scrtext_s = 'A'.
728.       WHEN 'FLAG2'.
729.         <p>-scrtext_l = 'Change B'.
730.         <p>-scrtext_m = 'C-Flg B'.
731.         <p>-scrtext_s = 'B'.
732.  
733.       WHEN OTHERS.
734.     ENDCASE.
735.   ENDLOOP.
736.  
737. ENDFORM .                    "prepare_field_catalog
738. *&--------------------------------------------------------------------*
739. *&      Form  prepare_layout
740. *&--------------------------------------------------------------------*
741. *       text
742. *---------------------------------------------------------------------*
743. *      -->PS_LAYOUT  text
744. *---------------------------------------------------------------------*
745. FORM prepare_layout CHANGING ps_layout TYPE lvc_s_layo.
746.  
747.  
748.   ps_layout-zebra = 'X' .
749.   ps_layout-numc_total = ' '.
750.   ps_layout-no_merging = 'X'.
751.   ps_layout-no_rowmark = ' '.
752.   ps_layout-sel_mode = 'A'.
753.  
754. ENDFORM.                    "prepare_layout

GeSHi ©

Der benötigte RFC-Enabled Funktionsbaustein.

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. FUNCTION Z_BC_READSFXML.
2. *"----------------------------------------------------------------------
3. *"*"Local Interface:
4. *"  IMPORTING
5. *"     VALUE(I_FORM) TYPE  TDSFNAME
6. *"     VALUE(I_LANGU) TYPE  SPRAS DEFAULT 'E'
7. *"  TABLES
8. *"      SFTAB STRUCTURE  SMUM_XMLTB
9. *"      RETURN STRUCTURE  BAPIRET2 OPTIONAL
10. *"  EXCEPTIONS
11. *"      FORM_NOT_EXIST
12. *"----------------------------------------------------------------------
13.   CONSTANTS: c_xml_ns_uri_sf(255)  TYPE c
14.       VALUE 'urn:sap-com:SmartForms:2000:internal-structure', "#EC NOTEXT
15.              c_xml_ns_uri_ifr(255) TYPE c
16.                                      VALUE 'urn:sap-com:sdixml-ifr:2000'. "#EC NOTEXT
17.  
18.   TYPES tyt_tab_xml TYPE TABLE OF smum_xmltb.
19.  
20.  
21.   TYPES: t_gnode  TYPE ssfgnode,
22.          t_gnodes TYPE tsfgnode.
23.  
24.  
25.   DATA: l_filename    TYPE string,
26.         l_file_filter TYPE string,
27.         l_user_action TYPE i.
28.   DATA: l_element TYPE REF TO if_ixml_element.
29.   DATA: l_language_str TYPE string,
30.         l_language(2)  TYPE c.
31.   DATA: l_lines             TYPE i,
32.         l_splitted_name_tab TYPE TABLE OF string.
33.   DATA: l_stylename  TYPE tdssname,
34.         l_stylevari  TYPE tdvariant,
35.         l_save_style TYPE tdssname.
36.  
37.  
38.   DATA: g_ixml              TYPE REF TO if_ixml,
39.         xml_document        TYPE REF TO if_ixml_document,
40.         xml_element         TYPE REF TO if_ixml_element,
41.         xml_ns_prefix_sf    TYPE string,
42.         xml_ns_uri_sf       TYPE string,
43.         xml_ns_uri_ifr      TYPE string,
44.         xml_macro_name      TYPE string,
45.         xml_macro_rc        TYPE i,
46.         xml_macro_objt      TYPE stxfobjt,
47.         xml_macro_text      TYPE stxftxt,
48.         xml_macro_tline     TYPE tline,
49.         xml_upload_language TYPE tdspras.
50.  
51.   TYPES: t_raw(250) TYPE x.
52.  
53.   DATA: xml_xtable        TYPE TABLE OF t_raw WITH HEADER LINE,
54.         xml_document_size TYPE i.
55.  
56.  
57.   DATA: sform             TYPE REF TO cl_ssf_fb_smart_form.
58.  
59. * Namen der aktuell bearbeiteten Objekte
60.   DATA: formname    TYPE tdsfname,     " Name des Formulars
61.         variant     TYPE tdvariant,    " Name der Formularvariante
62.         language    TYPE sy-langu,     " Bearbeitungssprache
63.         fmnumb      TYPE tdfmnumb,     " Nummer des zugeordneten Fb
64.         fmnumb_test TYPE tdfmnumb.     " Fb zum Test der inaktiven Fassung
65.  
66.  
67.   DATA: gv_xml_xstring TYPE          xstring,
68.         gv_size        TYPE          sy-tabix.
69.  
70.   DATA ls_admin TYPE stxfadm.
71.  
72.   SELECT SINGLE * FROM stxfadm INTO ls_admin WHERE formname = i_form.
73.  
74.   IF ls_admin IS INITIAL.
75.     RAISE form_not_exist.
76.   ELSE.
77.     formname = i_form.
78.   ENDIF.
79.  
80.   IF i_langu IS INITIAL.
81.     language =  ls_admin-masterlang.
82.   ELSE.
83.     language = i_langu.
84.   ENDIF.
85.  
86. * create form object
87.   CREATE OBJECT sform.
88.  
89.   CALL METHOD sform->load
90.     EXPORTING
91.       im_formname    = formname
92.       im_language    = language
93.       im_active      = space
94.     IMPORTING
95.       ex_fmnumb      = fmnumb
96.       ex_fmnumb_test = fmnumb_test.
97.  
98.   IF g_ixml IS INITIAL.
99.     g_ixml          = cl_ixml=>create( ).
100.   ENDIF.
101.  
102.   xml_document      = g_ixml->create_document( ).
103.   xml_ns_prefix_sf  = 'sf'.
104.   xml_ns_uri_sf     = c_xml_ns_uri_sf.
105.   xml_ns_uri_ifr    = c_xml_ns_uri_ifr.
106.   CLEAR: xml_document_size, xml_xtable[].
107.   sform->xml_init( ).
108.  
109. * create XML for the entire smart form
110.   CALL METHOD sform->xml_download
111.     EXPORTING
112.       parent   = xml_document
113.     CHANGING
114.       document = xml_document.
115.  
116. * namespace
117.   l_element  = xml_document->get_root_element( ).
118.   l_element->set_attribute( name      = xml_ns_prefix_sf
119.                             namespace = 'xmlns'
120.                             value     = xml_ns_uri_sf ).
121.   l_element->set_attribute( name  = 'xmlns'
122.                             value = xml_ns_uri_ifr ).
123.  
124. * language
125.   WRITE language TO l_language.
126.   l_language_str = l_language.
127.   xml_macro_rc = l_element->set_attribute(
128.                       name      = 'language'
129.                       namespace = xml_ns_prefix_sf
130.                       value     = l_language_str ).
131.  
132.  
133.   CALL FUNCTION 'SDIXML_DOM_TO_XML'
134.     EXPORTING
135.       document      = xml_document
136. *     PRETTY_PRINT  = ' '
137.     IMPORTING
138.       xml_as_string = gv_xml_xstring
139.       size          = gv_size
140.     EXCEPTIONS
141.       no_document   = 1
142.       OTHERS        = 2.
143.  
144. *== Convert XML to itab
145.   CALL FUNCTION 'SMUM_XML_PARSE'
146.     EXPORTING
147.       xml_input = gv_xml_xstring
148.     TABLES
149.       xml_table = sftab
150.       return    = return.
151.  
152.  
153. ENDFUNCTION.

GeSHi ©