Rätsel mit Radiobuttons

[Ilja583]

Die Darstellung liegt aber eher an unterschiedlichen GUI-Versionen

Mag sein - aber die Screenshots aus dem IDES und dem "normalen" 4.6er System wurden mit derselben GUI (6.40, Patchlvl 1 )gemacht und ein Kollege einen Stuhl weiter hat denselben Effekt mit einer 6.20, Patch 32 Gui

[Ilja583]

Erstmal Gratulation an alle, die hier eine Lösung oder einen Lösungshinweis gepostet haben.

Wie man ( mal wieder ) sieht, gibt es mehrere Wege die nach Rom führen.

Ganz allgemein kann man sagen, dass die Lösung darauf beruht einen weiteren (anfangs aktiven) Radiobutton "RB3" mit anzulegen und diesen danach so zu verstecken, dass der User diesen nicht mehr zu sehen bekommt.

Wer das selber probiert hat wird feststellen, dass SAP da ziemlich geschickt vorgeht um die am Anfang dieses Threads dargestellte Kombination eigentlich nicht zuzulassen - die simplen Methoden wie "no-display" oder "LOOP AT SCREEN + SCREEN-INVISIBLE = 1" führen entweder zu Syntaxfehlern oder dazu, dass einer der sichtbaren Buttons als aktiv gekennzeichnet wird.

Somit gibt es also mindestens 2 Möglichkeiten dies zu bewerkstelligen.

Methode A)
Diese Methode ( wohl die elegantere ) versucht grob gesagt den 3. Radiobutton "unter" den 2. Radiobutton zu legen. Dies ist mit "normalen" Mitteln nicht möglich - aber die nur für den internen Gebrauch bestimmten Befehle IMPORT DYNPRO und GENERATE DYNPRO lassen dies zu.
Das Beispielcoding von Gast macht das im folgenden Block (vor dem Senden des Selektionsbildes)

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. LOAD-OF-PROGRAM.
2.   id-prog = sy-repid. id-dnum = '1000'.
3.   IMPORT DYNPRO h f e m ID id.
4.   f-line = '02'.
5.   MODIFY f TRANSPORTING LINE where LINE eq x.
6.   GENERATE DYNPRO h f e m ID id MESSAGE a LINE b WORD c.
7.   FREE: f, e, m.
8.   CALL FUNCTION 'DB_COMMIT'.
9.  

GeSHi ©

Methode B
Auch hier wird der 3. Button versteckt - jedoch ein wenig anders.

Zunächst wird ein "normales" Dynpro auf den Selektionsbildschirm gebunden via " SELECTION-SCREEN BEGIN OF TABBED BLOCK "

Dieser Screen wird angelegt (als Subscreen natürlich) mit der Größe 3 Zeilen x 40 Spalten, damit keine Scrollbalken entstehen.

Leider reicht dies noch nicht aus. Auf diesen 1. Subscreen wird ein den ganzen Bereich ausfüllender 2. Subscreen gelegt.

Der Dynpro, den man nun in diesen 2. Subscreenbereich legt, definiert man größer als die 3x40 Ausmaße ( etwa einfach die Standardmaße beibehalten). Dieser 2. Subscreen wird dann nachher beim Ausführen des Programms nach der 3. Zeile abgeschnitten dargestellt - aber alle Inhalte desselben sind aktiv auf der Seite vorhanden

Theoretisch reicht dies aus, um dem Betrachter obiges Phänomen vorzutäuschen, wenn nicht der andere Gast noch nach Variantenspeichermöglichkeiten gefragt hätte.

In diesem Fall nun muss man (nicht FI hören lassen) doppelte Buchführung betreiben.
RB1 - RB3 werden als normale Felder unsichtbar auf den Selektionsbildschirm gelegt und die sichtbaren Buttons auf dem inkludierten Dynpro werden RB1_D bis RB3_D angelegt aber mit RB1 - RB3 beschriftet.
Danach noch dafür sorgen, dass die "eigentlichen" Parameter RB1 - RB3 sich genauso verhalten wie die sichtbaren Parameter RB1_D - RB3_D ( ein wenig tricky wg. des Feldtransports bei Radiobuttons )

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. REPORT.
2.  
3. DATA: rb1_d TYPE as4flag,
4.       rb2_d TYPE as4flag,
5.       rb3_d TYPE as4flag.
6.  
7. TABLES: sscrfields.
8.  
9. SELECTION-SCREEN BEGIN OF BLOCK bl0 WITH FRAME.
10. SELECTION-SCREEN BEGIN OF TABBED BLOCK bl1 FOR 3 LINES.
11. SELECTION-SCREEN END OF BLOCK bl1.
12. SELECT-OPTIONS: s_datum FOR sy-datum.
13. SELECTION-SCREEN END OF BLOCK bl0.
14.  
15. PARAMETERS: rb1 TYPE as4flag NO-DISPLAY,
16.             rb2 TYPE as4flag NO-DISPLAY,
17.             rb3 TYPE as4flag NO-DISPLAY.
18.  
19.  
20.  
21. INITIALIZATION.
22.   bl1-prog  = sy-repid.
23.   bl1-dynnr = '8000'.
24.   rb3 = 'X'.
25.  
26. AT SELECTION-SCREEN OUTPUT.
27.   rb1_d = rb1.
28.   rb2_d = rb2.
29.   rb3_d = rb3.
30.  
31. AT SELECTION-SCREEN.
32.   PERFORM get_buttons.
33. * call screen 8000.
34. * call screen 8001.
35.  
36. END-OF-SELECTION.
37.   WRITE:/ 'RB1=',rb1,
38.         / 'RB2=',rb2,
39.         / 'RB3=',rb3.
40.  
41.  
42.  
43. *&---------------------------------------------------------------------*
44. *&      Form  get_buttons
45. *&---------------------------------------------------------------------*
46. FORM get_buttons.
47.   DATA: repid TYPE syrepid,
48.         dynnr TYPE sydynnr,
49.         dynpfields TYPE STANDARD TABLE OF dynpread,
50.         wa_df      LIKE LINE OF dynpfields,
51.         zeilen     TYPE i.
52.  
53.   dynnr = '8001'.
54.   repid = sy-repid.
55.  
56.   CALL FUNCTION 'DYNP_VALUES_READ'
57.        EXPORTING
58.             dyname               = repid
59.             dynumb               = dynnr
60.             request              = 'A'
61.        TABLES
62.             dynpfields           = dynpfields
63.        EXCEPTIONS
64.             invalid_abapworkarea = 1
65.             invalid_dynprofield  = 2
66.             invalid_dynproname   = 3
67.             invalid_dynpronummer = 4
68.             invalid_request      = 5
69.             no_fielddescription  = 6
70.             invalid_parameter    = 7
71.             undefind_error       = 8
72.             double_conversion    = 9
73.             stepl_not_found      = 10
74.             OTHERS               = 11.
75.  
76.   CASE 'X'.
77.     WHEN rb1.  DELETE dynpfields WHERE fieldname = 'RB1_D'.
78.     WHEN rb2.  DELETE dynpfields WHERE fieldname = 'RB2_D'.
79.     WHEN rb3.  DELETE dynpfields WHERE fieldname = 'RB3_D'.
80.   ENDCASE.
81.   DELETE dynpfields WHERE fieldvalue = space
82.                       AND ( fieldname = 'RB1_D' OR
83.                             fieldname = 'RB2_D' OR
84.                             fieldname = 'RB3_D' ).
85.   CHECK NOT dynpfields IS INITIAL.
86.  
87.   rb1 = rb2 = rb3 = space.
88.   LOOP AT dynpfields INTO wa_df WHERE fieldvalue = 'X'.
89.     CASE wa_df-fieldname.
90.       WHEN 'RB1_D'.rb1 = 'X'.
91.       WHEN 'RB2_D'.rb2 = 'X'.
92.       WHEN 'RB3_D'.rb3 = 'X'.
93.     ENDCASE.
94.   ENDLOOP.
95.  
96. ENDFORM.                               " get_buttons

GeSHi ©

Dynproablauflogik von Subscreen 8000 ( Ausmaße 3 Zeilen x 40 Spalten )

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. PROCESS BEFORE OUTPUT.
2.   CALL SUBSCREEN sub2 INCLUDING sy-repid '8001'.
3. * MODULE STATUS_8000.
4. *
5. PROCESS AFTER INPUT.
6.   CALL SUBSCREEN sub2.
7. * MODULE USER_COMMAND_8000.

GeSHi ©

Dynproablauflogik von Subscreen 8001 ( Ausmaße 28 Zeilen x 240 Spalten )

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. keine

GeSHi ©

[Willy1492]

Methode A)
Diese Methode ( wohl die elegantere ) versucht grob gesagt den 3. Radiobutton "unter" den 2. Radiobutton zu legen. Dies ist mit "normalen" Mitteln nicht möglich - aber die nur für den internen Gebrauch bestimmten Befehle IMPORT DYNPRO und GENERATE DYNPRO lassen dies zu.

Also wenn man hier überhaupt von "elegant" reden kann (ich würde erst mal versuchen, dem Anwender eine solche Anforderung auszureden), dann hat Deine Methode doch einige Vorteile:
-sie funktioniert scheinbar ab Release 4.6 unabhängig von Frontend-Einstellungen, -Version und SAP-Release
-sie nutzt nur von SAP auch freigegebene Anweisungen

Bei GENERATE DYNPRO sieht das Ergebnis ja offenbar bei jedem Anwender anders aus, viel Spaß beim Support.
Und SAP wird sich auch weigern, eine Lösung für evtl. später auftretende Probleme zu liefern (z.B. wenn zukünftig bei sich überschneidenden Feldern einfach ein Laufzeitfehler erzeugt wird).

Und wenn man wirklich GENERATE DYNPRO nimmt, sollte man erstens auch den Fall beachten, dass das Selektionsdynpro noch gar nicht existiert (z.B. nach dem ersten Transport des Programms in ein neues System):

Dazu muss nach

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1.   IMPORT DYNPRO h f e m ID id.

GeSHi ©

zum Beispiel folgender Code ergänzt werden:

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1.   IF sy-subrc NE 0.
2.     SUBMIT rsdbgena
3.             WITH repname EQ id-prog
4.             EXPORTING LIST TO MEMORY
5.             AND RETURN.
6.     IMPORT DYNPRO h f e m ID id.
7.   ENDIF.
8.  

GeSHi ©

Damit wird, falls das Dynpro nicht existiert, das Dynpro generiert und dann noch mal importiert.

Und zweitens kann man sich das GENERATE DYNPRO ... sparen, wenn nach MODIFY f ... SY-SUBRC nicht 0 ist, denn dann gab es offenbar nichts mehr zu ändern.

[Willy1492]

Mit

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. PARAMETERS rb1 RADIOBUTTON GROUP r.
2. PARAMETERS rb2 RADIOBUTTON GROUP r.
3. SELECTION-SCREEN BEGIN OF LINE.
4. SELECTION-SCREEN POSITION 38.
5. PARAMETERS rb3 RADIOBUTTON GROUP r DEFAULT 'X'.
6. SELECTION-SCREEN END OF LINE.

GeSHi ©

und

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1.     LOOP AT f WHERE LINE EQ 3.
2.       add 1 to f-line.
3.       MODIFY f TRANSPORTING line.
4.     ENDLOOP.

GeSHi ©

kann man den 3. Radiobutton übrigens unter dem LOW-Feld der SELECT-OPTION verstecken und hat ein wenig mehr Spielraum, was die Positionierung betrifft